Greetings,
Kindly requesting you to suggest on use of global variables.
Can we use a result from a collection populated by one package into a different package?
I tried below piece of code but failed, please suggest if it is possible or not?

CREATE OR REPLACE PACKAGE p1
AS
CURSOR c1 (p_employee_id employees.employee_id%TYPE)
IS
SELECT *
FROM employees
WHERE employee_id = p_employee_id;

TYPE aat_e IS TABLE OF c1%ROWTYPE INDEX BY PLS_INTEGER;

lv_e aat_e;

PROCEDURE p1 (p_employee_id employees.employee_id%TYPE);
END p1;
/
CREATE OR REPLACE PACKAGE BODY APPS.p1
AS
PROCEDURE p1 (p_employee_id IN employees.employee_id%TYPE)
AS
BEGIN
OPEN c1 (p_employee_id);

FETCH c1
BULK COLLECT INTO lv_e;

CLOSE c1;

FOR i IN 1 .. lv_e.COUNT
LOOP
DBMS_OUTPUT.PUT_LINE (lv_e(i).first_name);
END LOOP;

ct.p1;

END p1;
END p1;
/
CREATE OR REPLACE PACKAGE APPS.p2
AS
PROCEDURE p2 (p_employee_id IN employees.employee_id%TYPE);
END p2;
/

CREATE OR REPLACE PACKAGE BODY p2
AS
PROCEDURE p2 (p_employee_id IN employees.employee_id%TYPE)
IS
lv_details employees%ROWTYPE;
BEGIN
lv_details := p_employee_id;
p1.p1 (lv_details);

SELECT *
INTO lv_detals
FROM employees
WHERE first_name = p1.lv_e (i).first_name;

DBMS_OUTPUT.put_line (lv_details.employee_id);
END p2;
END p2;

create table employees as
  select * from hr.employees;

create or replace package p1
as
  cursor c1 ( p_employee_id employees.employee_id%type )
  is
    select * from employees where employee_id = p_employee_id;
  type aat_e
  is table of c1%rowtype index by pls_integer;
  lv_e aat_e;
  procedure p1 (
      p_employee_id employees.employee_id%type ) ;
end p1;
/
create or replace package body p1
as
  procedure p1 (
      p_employee_id in employees.employee_id%type )
  as
  begin
    open c1 ( p_employee_id ) ;
    fetch c1 bulk collect into lv_e;
    close c1;
    for i in 1 .. lv_e.count
    loop
      dbms_output.put_line ( lv_e ( i ) .first_name ) ;
    end loop;
  end p1;
end p1;
/
create or replace package p2
as
  procedure p2 (
      p_employee_id in employees.employee_id%type ) ;
end p2;
/
create or replace package body p2
as
  procedure p2 (
      p_employee_id in employees.employee_id%type )
  is
    lv_details employees%rowtype;
  begin
    p1.p1 ( p_employee_id ) ;
    select *
    into lv_details
    from employees
    where first_name = p1.lv_e ( 1 ) .first_name;
    dbms_output.put_line ( lv_details.employee_id ) ;
  end p2;
end p2;
/

exec p2.p2(101);

Neena
101