I would recommend if you are going slow by slow to use

update emp set ....
if sql%rowcount = 0
the
insert emp;
end if;


Less code, more efficient (else we need to select from dual). However, if you want to do this in bulk (even more efficient than slow by slow), you would do this:

ops$tkyte@ORA10G> create table emp as select empno, ename from scott.emp;

Table created.

ops$tkyte@ORA10G> create table new_emp as select empno, ename from scott.emp where mod(empno,2)=0;

Table created.

ops$tkyte@ORA10G>
ops$tkyte@ORA10G> create or replace type myScalarType as object
2 ( empno number, ename varchar2(30) )
3 /

Type created.

ops$tkyte@ORA10G> create or replace type myTableType as table of myScalarType
2 /

Type created.

ops$tkyte@ORA10G>
ops$tkyte@ORA10G>
ops$tkyte@ORA10G> declare
2 l_data myTableType;
3 l_limit number default 10;
4
5 cursor c is select myScalarType(empno,ename) from emp;
6 begin
7 open c;
8 loop
9 fetch c bulk collect into l_data limit l_limit;
10 if ( l_data.count > 0 )
11 then
12 for i in 1 .. l_data.count
13 loop
14 l_data(i).ename := initcap( l_data(i).ename );
15 end loop;
16 merge into new_emp
17 using ( select * from table(cast(l_data as myTableType))) X
18 on (new_emp.empno = x.empno)
19 when matched then update set ename = x.ename
20 when not matched then insert ( empno, ename ) values ( x.empno, x.ename );
21 end if;
22 exit when c%notfound;
23 end loop;
24 end;
25 /

PL/SQL procedure successfully completed.