you can derive this value.


Using a procedure like this, we can get details:


ops$tkyte@ORA920> create or replace procedure show_space
  2  ( p_segname in varchar2,
  3    p_owner   in varchar2 default user,
  4    p_type    in varchar2 default 'TABLE',
  5    p_partition in varchar2 default NULL )
  6  authid current_user
  7  as
  8      l_free_blks                 number;
  9
 10      l_total_blocks              number;
 11      l_total_bytes               number;
 12      l_unused_blocks             number;
 13      l_unused_bytes              number;
 14      l_LastUsedExtFileId         number;
 15      l_LastUsedExtBlockId        number;
 16      l_LAST_USED_BLOCK           number;
 17      l_segment_space_mgmt        varchar2(255);
 18      l_unformatted_blocks number;
 19      l_unformatted_bytes number;
 20      l_fs1_blocks number; l_fs1_bytes number;
 21      l_fs2_blocks number; l_fs2_bytes number;
 22      l_fs3_blocks number; l_fs3_bytes number;
 23      l_fs4_blocks number; l_fs4_bytes number;
 24      l_full_blocks number; l_full_bytes number;
 25
 26      procedure p( p_label in varchar2, p_num in number )
 27      is
 28      begin
 29          dbms_output.put_line( rpad(p_label,40,'.') ||
 30                                to_char(p_num,'999,999,999,999') );
 31      end;
 32  begin
 33    select ts.segment_space_management
 34      into l_segment_space_mgmt
 35      from dba_segments seg,  dba_tablespaces  ts
 36     where seg.segment_name    = p_segname
 37       and   seg.owner           = p_owner
 38       and   seg.tablespace_name = ts.tablespace_name;
 39
 40    if l_segment_space_mgmt = 'AUTO'
 41    then
 42       dbms_space.space_usage (
 43         p_owner,
 44         p_segname,
 45         p_type,
 46         l_unformatted_blocks,
 47         l_unformatted_bytes,
 48         l_fs1_blocks, l_fs1_bytes,
 49         l_fs2_blocks, l_fs2_bytes,
 50         l_fs3_blocks, l_fs3_bytes,
 51         l_fs4_blocks, l_fs4_bytes,
 52         l_full_blocks, l_full_bytes
 53       );
 54       --
 55       p( 'Unformatted Blocks ', l_unformatted_blocks );
 56       p( 'FS1 Blocks (0-25)  ', l_fs1_blocks );
 57       p( 'FS2 Blocks (25-50) ', l_fs2_blocks );
 58       p( 'FS3 Blocks (50-75) ', l_fs3_blocks );
 59       p( 'FS4 Blocks (75-100)', l_fs4_blocks );
 60       p( 'Full Blocks        ', l_full_blocks );
 61    else
 62       dbms_space.free_blocks(
 63         segment_owner     => p_owner,
 64         segment_name      => p_segname,
 65         segment_type      => p_type,
 66         freelist_group_id => 0,
 67         free_blks         => l_free_blks
 68       );
 69       --
 70       p( 'Free Blocks', l_free_blks );
 71    end if;
 72      dbms_space.unused_space
 73      ( segment_owner     => p_owner,
 74        segment_name      => p_segname,
 75        segment_type      => p_type,
 76            partition_name    => p_partition,
 77        total_blocks      => l_total_blocks,
 78        total_bytes       => l_total_bytes,
 79        unused_blocks     => l_unused_blocks,
 80        unused_bytes      => l_unused_bytes,
 81        LAST_USED_EXTENT_FILE_ID => l_LastUsedExtFileId,
 82        LAST_USED_EXTENT_BLOCK_ID => l_LastUsedExtBlockId,
 83        LAST_USED_BLOCK => l_LAST_USED_BLOCK );
 84
 85      p( 'Total Blocks', l_total_blocks );
 86      p( 'Total Bytes', l_total_bytes );
 87      p( 'Total MBytes', trunc(l_total_bytes/1024/1024) );
 88      p( 'Unused Blocks', l_unused_blocks );
 89      p( 'Unused Bytes', l_unused_bytes );
 90      p( 'Last Used Ext FileId', l_LastUsedExtFileId );
 91      p( 'Last Used Ext BlockId', l_LastUsedExtBlockId );
 92      p( 'Last Used Block', l_LAST_USED_BLOCK );
 93  end;
 94  /

Procedure created.

ops$tkyte@ORA920> set define on
ops$tkyte@ORA920> exec show_space( 'T' )
Unformatted Blocks .....................               0
FS1 Blocks (0-25)  .....................               0
FS2 Blocks (25-50) .....................               0
FS3 Blocks (50-75) .....................               0
FS4 Blocks (75-100).....................               0
Full Blocks        .....................             411
Total Blocks............................             512
Total Bytes.............................       4,194,304
Total MBytes............................               4
Unused Blocks...........................              85
Unused Bytes............................         696,320
Last Used Ext FileId....................               8
Last Used Ext BlockId...................             392
Last Used Block.........................              43

PL/SQL procedure successfully completed.


<b>that shows there are 411 "data" blocks, blocks with data on them.  There are 512 total blocks in the segment -- 85 of which are totally unused (above the real HWM, not touched).

Well, 512 - 411 - 85 = 16, there are 16 blocks "unaccounted for".  they are used by Oracle to manage this segment.</b>
 

ops$tkyte%ORA11GR1> set numformat 999,999,999,999,999,999,999,999
ops$tkyte%ORA11GR1> select power(2,48) from dual;

                     POWER(2,48)
--------------------------------
             281,474,976,710,656

ops$tkyte%ORA11GR1> select power(2,48)/1000/60/60/24/366 from dual;

   POWER(2,48)/1000/60/60/24/366
--------------------------------
                           8,901