You didn't post the entire error stack, but I think I know what it is - ora-4068, existing state of packages discarded.

In short, your code maintains a state (has global variables).
Someone has recompiled your code - either explicitly or implicitly.
And they did this AFTER you established a state, thus they wiped it out.

we have to tell you "this happened"


in the following, we create a package that has a global variable.

We have a trigger that invokes this package.

We run it twice - no worries, it works.

In another session, we cause the code to recompile - note that it is always valid, it never is invalid!

When we try to run the trigger again - error. We have to tell you that your package was wiped out, your code must depend on these globals (or you wouldn't use them because we know that global variables are in general evil evil things and we'd never use them unless there was no other way!)

Later, when we try the insert again, it works (because we told you - we are off the hook now, caveat emptor)

ops$tkyte%ORA10GR2> create or replace package stateful_pkg
  2  as
  3          procedure p;
  4  end;
  5  /

Package created.

ops$tkyte%ORA10GR2> create or replace package body stateful_pkg
  2  as
  3          g_another_global_variable number := 0;
  4
  5          procedure p
  6          is
  7          begin
  8                  g_another_global_variable := g_another_global_variable+2;
  9          end;
 10  end;
 11  /

Package body created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> create table t ( x int );

Table created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> create or replace trigger t_trigger
  2  before insert on t
  3  for each row
  4  begin
  5          stateful_pkg.p;
  6  end;
  7  /

Trigger created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> insert into t values ( 1 );

1 row created.

ops$tkyte%ORA10GR2> insert into t values ( 2 );

1 row created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> set echo off
in another session - execute this:
create or replace package stateful_pkg
as
-- I''ve changed something...
type array is table of number index by binary_integer;
g_data array;
procedure p;
end;
/

ops$tkyte%ORA10GR2> insert into t values ( 3 );
insert into t values ( 3 )
            *
ERROR at line 1:
ORA-04068: existing state of packages has been discarded
ORA-04061: existing state of package "OPS$TKYTE.STATEFUL_PKG" has been
invalidated
ORA-04065: not executed, altered or dropped package "OPS$TKYTE.STATEFUL_PKG"
ORA-06508: PL/SQL: could not find program unit being called:
"OPS$TKYTE.STATEFUL_PKG"
ORA-06512: at "OPS$TKYTE.T_TRIGGER", line 2
ORA-04088: error during execution of trigger 'OPS$TKYTE.T_TRIGGER'


ops$tkyte%ORA10GR2> insert into t values ( 3 );

1 row created.