No you cannot name it, but you can *rename* it. So just have a job that runs (say) nightly that takes care of it.
Here's a code snippet from a routine I used to have to rename interval partitions for timestamps, but you can modify it to suit your needs
declare
l_high_value varchar2(4000);
l_partition_boundary date;
l_parname varchar2(40);
l_ddl varchar2(4000);
BEGIN
--
-- then we clean up and rename interval partitions to make life easier for us
--
for i in (
select a.owner, a.table_name, a.partitioning_type, t.partition_name, t.high_value, a.interval
from all_part_tables a, all_tab_partitions t
where a.owner in (...)
and a.partitioning_type = 'RANGE'
and a.table_name not like 'BIN$%'
and a.interval is not null
and t.table_owner = a.owner
and t.table_name = a.table_name
and regexp_like(t.partition_name,'^SYS_P[[:digit:]]{1,10}') )
loop
begin
l_high_value := i.high_value;
execute immediate 'select '||l_high_value||'-1 from dual' into l_partition_boundary;
if upper(i.interval) like 'NUMTODSINTERVAL%' then
l_parname := substr(i.table_name,1,21)||'_'||to_char(l_partition_boundary,'YYYYMMDD');
elsif upper(i.interval) like 'NUMTOYMINTERVAL%MONTH%' then
l_parname := substr(i.table_name,1,23)||'_'||to_char(l_partition_boundary,'YYYYMM');
elsif upper(i.interval) like 'NUMTOYMINTERVAL%YEAR%' then
l_parname := substr(i.table_name,1,25)||'_'||to_char(l_partition_boundary,'YYYY');
elsif upper(i.interval) like 'INTERVAL''%''DAY%' then
l_parname := substr(i.table_name,1,21)||'_'||to_char(l_partition_boundary,'YYYYMMDD');
elsif upper(i.interval) like 'INTERVAL''%''MONTH%' then
l_parname := substr(i.table_name,1,23)||'_'||to_char(l_partition_boundary,'YYYYMM');
elsif upper(i.interval) like 'INTERVAL''%''YEAR%' then
l_parname := substr(i.table_name,1,25)||'_'||to_char(l_partition_boundary,'YYYY');
else
-- unknown interval format... log it and skip over this partition
l_parname := null;
logger ('Cannot determine correct partition name for table ' || i.table_name || ' partition ' || i.partition_name);
end if;
exception
when others then
l_parname := null;
logger ('Cannot determine correct partition name for table ' || i.table_name || ' partition ' || i.partition_name||' hi='||l_high_value);
end;
if (l_parname is not null) then
l_ddl := 'alter table '||i.owner||'.'||i.table_name||' rename partition '||i.partition_name||' to '||l_parname;
logger(l_ddl);
begin
execute immediate l_ddl;
exception
when others then
logger('Failed with '||sqlerrm);
end;
end if;
end loop;
--
-- then we can use those new partition names to do the same for indexes
--
for i in (
with tabpar as (
select /*+ materialize */
a.owner, a.table_name, a.partitioning_type, t.partition_name, t.partition_position
from all_part_tables a, all_tab_partitions t
where a.owner in (...)
and a.partitioning_type = 'RANGE'
and a.table_name not like 'BIN$%'
and a.interval is not null
and t.table_owner = a.owner
and t.table_name = a.table_name
), indpar as (
select /*+ materialize */
ai.owner, ai.table_name, ai.index_name, i.partition_name, i.partition_position
from all_part_indexes ai, all_ind_partitions i
where ai.owner in (...)
and ai.partitioning_type = 'RANGE'
and ai.table_name not like 'BIN$%'
and ai.interval is not null
and i.index_owner = ai.owner
and ai.index_name = i.index_name
and ai.locality = 'LOCAL'
)
select t.owner, t.table_name, t.partition_name new_par_name, i.index_name, i.partition_name
from tabpar t, indpar i
where i.owner = t.owner
and i.table_name = t.table_name
and i.partition_position = t.partition_position
and not regexp_like(t.partition_name,'^SYS_P[[:digit:]]{1,10}')
and regexp_like(i.partition_name,'^SYS_P[[:digit:]]{1,10}')
)
loop
l_ddl := 'alter index '||i.owner||'.'||i.index_name||' rename partition '||i.partition_name||' to '||i.new_par_name;
logger(l_ddl);
begin
execute immediate l_ddl;
exception
when others then
logger('Failed with '||sqlerrm);
end;
end loop;
END;