You dont want to do it directly from a trigger, because someone might roll back the transaction - but you can't roll back a flat file write.

So you would do it like this:

a) trigger submits a job via dbms_job
b) commit will activate the job
c) job will perform the required steps, eg utl_file.

SQL> create table t ( deptno int );

Table created.

SQL>
SQL> create or replace
  2  procedure unload_Data is
  3    l_file         utl_file.file_type;
  4    l_dir          varchar2(100) := 'TEMP';
  5    l_filename     varchar2(100) := 'myfile.dat';
  6  begin
  7    l_file := utl_file.fopen(l_dir, l_filename, 'w');
  8    utl_file.put_line(l_file, 'Here is some data');
  9    utl_file.fclose(l_file);
 10  end;
 11  /

Procedure created.

SQL>
SQL> create or replace
  2  trigger t_trg
  3  after insert on t
  4  for each row
  5  declare
  6    j int;
  7  begin
  8    dbms_job.submit(j, 'unload_data;');
  9  end;
 10  /

Trigger created.

SQL>
SQL> insert into t values (10);

1 row created.

SQL> commit;

Commit complete.


SQL> host dir c:\temp\myfile.dat
 Volume in drive C is System
 Volume Serial Number is 7AD7-C05A

 Directory of c:\temp

20/02/2017  09:31 PM                19 myfile.dat
               1 File(s)             19 bytes
               0 Dir(s)  45,458,391,040 bytes free

SQL>