why not?

ops$tkyte%ORA10GR2> create table t1 ( x int, y int );

Table created.

ops$tkyte%ORA10GR2> insert into t1 select rownum, rownum+1 from all_users where rownum <= 5;

5 rows created.

ops$tkyte%ORA10GR2> create table t2 ( x int, y int, z int );

Table created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> select * from t2;

no rows selected

ops$tkyte%ORA10GR2> declare
  2          type array is table of t1%rowtype;
  3          l_data array;
  4  begin
  5          select * bulk collect into l_data from t1;
  6
  7          forall i in 1 .. l_data.count
  8                  insert into (select x, y from t2) values l_data(i);
  9  end;
 10  /

PL/SQL procedure successfully completed.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> select * from t2;

         X          Y          Z
---------- ---------- ----------
         1          2
         2          3
         3          4
         4          5
         5          6


in general, however, using COLLECTIONS as demonstrated makes it "infinitely" flexible as you can bind the collection and select whatever columns in whatever order you want.
 

ops$tkyte%ORA10GR2> create table t as select * from all_users;

Table created.

ops$tkyte%ORA10GR2> alter table t add constraint t_pk primary key(user_id);

Table altered.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> select * from t where rownum <= 2;

USERNAME                          USER_ID CREATED
------------------------------ ---------- ---------
USER2                                 135 01-MAY-07
USER1                                 134 01-MAY-07

ops$tkyte%ORA10GR2> declare
  2          type array1 is table of t%rowtype;
  3          type array2 is table of t.user_id%type index by binary_integer;
  4          l_data array1;
  5          l_ids  array2;
  6  begin
  7          select * bulk collect into l_data from t;
  8          for i in 1 .. l_data.count
  9          loop
 10                  l_ids(i) := l_data(i).user_id;
 11                  l_data(i).username := lower( l_data(i).username );
 12          end loop;
 13          forall i in 1 .. l_data.count
 14          update t set ROW = l_data(i) where user_id = l_ids(i);
 15  end;
 16  /

PL/SQL procedure successfully completed.

ops$tkyte%ORA10GR2> select * from t where rownum <= 2;

USERNAME                          USER_ID CREATED
------------------------------ ---------- ---------
user2                                 135 01-MAY-07
user1                                 134 01-MAY-07

ops$tkyte%ORA11GR1> create table t
  2  as
  3  select *
  4    from all_objects
  5   where rownum <= 542;

Table created.

ops$tkyte%ORA11GR1>
ops$tkyte%ORA11GR1> declare
  2
  3      cursor c is select rowid rid, object_name, object_type, owner
  4                    from t;
  5
  6      type l_array is table of C%rowtype;
  7      l_data l_array;
  8  begin
  9      open C;
 10      loop
 11          fetch C bulk collect into l_data LIMIT 100;
 12
 13          for i in 1 .. l_data.count
 14          loop
 15              null;
 16              /* .... some process that cannot be done in sql
 17                 goes here, for we all know that if it could
 18                 be done in sql without plsql, we'd be doing
 19                 it that way....
 20              */
 21          end loop;
 22
 23          forall i in 1 .. l_data.count
 24              update t set object_name = l_data(i).object_name, object_type = l_data(i).object_type, owner = l_data(i).owner where rowid = l_data(i).rid;
 25          exit when c%notfound;
 26      end loop;
 27      close c;
 28  end;
 29  /

PL/SQL procedure successfully completed.

ops$tkyte%ORA10GR2> declare
  2
  3      cursor c is select rowid rid, object_name, object_type, owner
  4                    from t;
  5
  6          type l_rowid_array is table of rowid;
  7          type l_oname_array is table of t.object_name%type;
  8          type l_otype_array is table of t.object_type%type;
  9          type l_owner_array is table of t.owner%type;
 10
 11          l_rids   l_rowid_array;
 12          l_onames l_oname_array;
 13          l_otypes l_otype_array;
 14          l_owners l_owner_array;
 15  begin
 16      open C;
 17      loop
 18          fetch C bulk collect into l_rids, l_onames, l_otypes, l_owners LIMIT 100;
 19
 20          for i in 1 .. l_rids.count
 21          loop
 22              null;
 23              /* .... some process that cannot be done in sql
 24                 goes here, for we all know that if it could
 25                 be done in sql without plsql, we'd be doing
 26                 it that way....
 27              */
 28          end loop;
 29
 30          forall i in 1 .. l_rids.count
 31              update t set object_name = l_onames(i), object_type = l_otypes(i), owner = l_owners(i) where rowid = l_rids(i);
 32          exit when c%notfound;
 33      end loop;
 34      close c;
 35  end;
 36  /

PL/SQL procedure successfully completed.

ops$tkyte%ORA10GR2> create or replace type myScalarType as object
  2  ( rid varchar2(30),
  3    oname varchar2(30),
  4    otype varchar2(30),
  5    owner varchar2(30)
  6  )
  7  /

Type created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> create or replace type myArrayType as table of myScalarType
  2  /

Type created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> declare
  2      cursor c is select myScalarType( rowid , object_name, object_type, owner )
  3                    from t;
  4
  5      l_data myArrayType;
  6  begin
  7      open C;
  8      loop
  9          fetch C bulk collect into l_data limit 100;
 10
 11          for i in 1 .. l_data.count
 12          loop
 13              null;
 14              /* .... some process that cannot be done in sql
 15                 goes here, for we all know that if it could
 16                 be done in sql without plsql, we'd be doing
 17                 it that way....
 18              */
 19          end loop;
 20
 21          merge into t
 22          using (select * from TABLE(l_data)) x
 23          on (t.rowid = chartorowid(x.rid))
 24          when matched then update set object_name = x.oname, object_type = x.otype, owner = x.owner;
 25
 26          exit when c%notfound;
 27      end loop;
 28      close c;
 29  end;
 30  /

PL/SQL procedure successfully completed.

begin

  insert into t1 (fi_name)
    select first_name
    from hr.employees@dbl_ab 
    where rownum <= 10

end;
/