I modified your procedure just a little to either register the session or receive a message:

ops$tkyte@ORA9IR2> create or replace procedure receive_message( p_register in boolean default true )
  2  as
  3       cALERT_TOPIC CONSTANT VARCHAR2(100) := 'some_topic';
  4       pvreceipt_message VARCHAR2(1000);
  5       pvstatus          VARCHAR2(1000);
  6  begin
  7          if (p_register)
  8          then
  9          DBMS_ALERT.REGISTER(cALERT_TOPIC);
 10      else
 11          DBMS_ALERT.WAITONE (cALERT_TOPIC
 12                         , pvreceipt_message
 13                         , pvstatus
 14                         , 300
 15                     );
 16          dbms_output.put_line(pvreceipt_message);
 17          end if;
 18  end;
 19  /
 
Procedure created.
 
ops$tkyte@ORA9IR2> exec signal_message( 'msg 0' );
PL/SQL procedure successfully completed.
 
ops$tkyte@ORA9IR2> exec receive_message;
PL/SQL procedure successfully completed.

<b>that shows that a message signaled BEFORE someone registered to listen for it just "goes away"</b>

 
ops$tkyte@ORA9IR2> exec signal_message( 'msg 1' );
PL/SQL procedure successfully completed.
 
ops$tkyte@ORA9IR2> exec signal_message( 'msg 2' );
PL/SQL procedure successfully completed.
 
ops$tkyte@ORA9IR2>
ops$tkyte@ORA9IR2> exec receive_message(FALSE);
msg 2
 
PL/SQL procedure successfully completed.

ops$tkyte@ORA9IR2> exec receive_message(FALSE);
<b>that just hangs - the multiply queued messages all overwrite eachother, they are NOT queued, there is no msg 1 to be picked up</b>


 

That is what I mean by "signals get lost" 

If 15 people signal -- only ONE of them get through, they do not queue up.


This is the way ALERTS work by design and there is no "fix", they are working correctly.

If you need messages to be delivered AT LEAST ONCE and AT MOST ONCE, you used the wrong package

You should use DBMS_AQ

 

ops$tkyte%ORA10GR2> create table params( job_id number primary key, p1 number, p2 timestamp, p3 varchar2(30) ) organization index;

Table created.

ops$tkyte%ORA10GR2> create table t as select params.*, systimestamp end_time from params;

Table created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> create or replace procedure proc( p_job in number )
  2  as
  3      l_rec params%rowtype;
  4  begin
  5      select * into l_rec from params where job_id = p_job;
  6      insert into t (job_id,p1,p2,p3,end_time)
  7      values (l_rec.job_id,l_rec.p1,l_rec.p2,l_rec.p3,systimestamp);
  8      delete from params where job_id = p_job;
  9      commit;
 10  end;
 11  /

Procedure created.

ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2>
ops$tkyte%ORA10GR2> declare
  2      l_job number;
  3      l_cnt number;
  4      l_msg long;
  5      l_status number;
  6  begin
  7      dbms_job.submit( l_job, 'proc(JOB); dbms_alert.signal(''MY_JOB'',null);' );
  8      insert into params (job_id,p1,p2,p3) values (l_job, 42, systimestamp, 'hello' );
  9
 10      dbms_job.submit( l_job, 'proc(JOB); dbms_alert.signal(''MY_JOB'',null);' );
 11      insert into params (job_id,p1,p2,p3) values (l_job, 55, systimestamp, 'world' );
 12
 13      dbms_alert.register( 'MY_JOB' );
 14      commit;
 15
 16      loop
 17          select count(*) into l_cnt from params where rownum=1;
 18          exit when l_cnt = 0;
 19          dbms_alert.waitone( 'MY_JOB', l_msg, l_status, 600 );
 20      end loop;
 21  end;
 22  /

PL/SQL procedure successfully completed.

ops$tkyte%ORA10GR2> select * from params;

no rows selected

ops$tkyte%ORA10GR2> select * from t;

    JOB_ID  P1 P2                           P3    END_TIME
---------- --- ---------------------------- ----- -----------------------------------
       349  42 11-MAY-09 08.55.53.167872 AM hello 11-MAY-09 08.55.56.018915 AM -04:00
       350  55 11-MAY-09 08.55.53.175672 AM world 11-MAY-09 08.55.56.030595 AM -04:00

Errors in file /home/ora10gr2/rdbms/log/ora10gr2_ora_5074.trc:
ORA-12012: error on auto execute of job 345
ORA-06550: line 1, column 107:
PLS-00201: identifier 'DBMS_ALERT' must be declared
ORA-06550: line 1, column 107:
PL/SQL: Statement ignored

...
begin
    for i in 1 .. numberofJobs
    loop
        dbms_job.submit( l_job, 'do_sql(job);' );
        insert into job_table values ( l_job, <whatever their parameters are> );
    end loop;
    dbms_alert.register( 'MULTIUSER' );
    commit;  -- jobs start running
    dbms_alert.waitone( 'MULTIUSER', l_msg, l_status, 600 );
    loop
        select count(*) into l_cnt from job_table where rownum=1;
        exit when l_cnt = 0;
        dbms_alert.waitone( 'MULTIUSER', l_msg, l_status, 600 );
    end loop;
end;

create or replace procedure do_sql( p_job in number )
as
    l_cursor sys_refcursor;
    l_rec    job_table%rowtype;
begin
    select * into l_rec from job_table where job = p_job;
...whatever...
    delete from job_table where job = p_job;
    dbms_alert.signal( 'MULTIUSER', '' );
    commit;
end;

ops$tkyte%ORA10GR2> declare
  2          l_junk   number;
  3          l_number number;
  4          l_str    varchar2(4000);
  5  begin
  6          l_junk := dbms_utility.GET_PARAMETER_VALUE( 'job_queue_processes', l_number, l_str );
  7          if ( nvl(l_number,0) = 0 )
  8          then
  9                  raise_application_error( -20001, 'job queues must be setup for this to run' );
 10          end if;
 11          dbms_output.put_line( 'we will have ' || l_number || ' concurrent jobs max' );
 12  end;
 13  /
we will have 10 concurrent jobs max

PL/SQL procedure successfully completed.