It would seem this feature (describe for a ref-cursor in PL/SQL) would be highly useful. I've seen requests for it quite often; not only on your site, but others as well.

Do you have any idea if they might be incorporating it in a [near] future version?

But strongly typed ref cursors can do that right (ie. describe the cursor)?

... you can use the following procedure:



procedure print (p_refcursor in sys_refcursor,
p_null_handling in number := 0)
as
l_xml xmltype;
l_context dbms_xmlgen.ctxhandle;
l_clob clob;

l_null_self_argument_exc exception;
pragma exception_init (l_null_self_argument_exc, -30625);

procedure print (p_msg in varchar2)
as
l_text varchar2(32000) := p_msg;
begin

loop
exit when l_text is null;
dbms_output.put_line(substr(l_text,1,250));
l_text:=substr(l_text, 251);
end loop;

end print;

begin

/*

Purpose: print debug information (ref cursor)

Remarks: outputs weakly typed cursor as XML

*/

-- get a handle on the ref cursor
l_context:=dbms_xmlgen.newcontext (p_refcursor);

/*

# DROP_NULLS CONSTANT NUMBER:= 0; (Default) Leaves out the tag for NULL elements.
# NULL_ATTR CONSTANT NUMBER:= 1; Sets xsi:nil="true".
# EMPTY_TAG CONSTANT NUMBER:= 2; Sets, for example, <foo/>.

*/

-- how to handle null values
dbms_xmlgen.setnullhandling (l_context, p_null_handling);

-- create XML from ref cursor
l_xml:=dbms_xmlgen.getxmltype (l_context, dbms_xmlgen.none);

print('Number of rows in ref cursor: ' || dbms_xmlgen.getnumrowsprocessed (l_context));

begin
l_clob:=l_xml.getclobval();
print('Size of XML document (anything over 32K will be truncated): ' || length(l_clob));
print(substr(l_clob,1,32000));
exception
when l_null_self_argument_exc then
print('Empty dataset.');
end;

end print;

then you can use this approach.
However, it fails if the resulting string is longer than 32K.

declare
cur sys_refcursor;

procedure p(p_str in varchar2) is
l_str long := p_str || chr(10);
l_piece long;
n number;
begin
loop
exit when l_str is null;
n := instr(l_str, chr(10));
l_piece := substr(l_str, 1, n - 1);
l_str := substr(l_str, n + 1);
loop
exit when l_piece is null;
dbms_output.put_line(substr(l_piece, 1, 250));
l_piece := substr(l_piece, 251);
end loop;
end loop;
end;

function print_refcursor(cur sys_refcursor) return varchar2 as
begin
return xmltype(cur) .getstringval();
end print_refcursor;

begin
open cur for
select * from all_objects where rownum < 3;

p(print_refcursor(cur));
end;
/

I am only pasting the code snippet after creating the sql string...

--In the declare section
out_result_cur SYS_REFCURSOR;
out_query_result CLOB;
qryCtx DBMS_XMLGEN.ctxHandle;

--In the executable section
OPEN out_result_cur FOR v_select_sql;

qryCtx := dbms_xmlgen.newCOntext(out_result_cur);
out_query_result := dbms_xmlgen.getXml(qryCtx);
dbms_xmlgen.closeContext(qryCtx);

print_clob(out_query_result);


PROCEDURE print_clob( p_clob IN CLOB )
IS
l_offset NUMBER DEFAULT 1;
BEGIN
LOOP
EXIT WHEN l_offset > DBMS_LOB.GETLENGTH(p_clob);
DBMS_OUTPUT.PUT_LINE( DBMS_LOB.SUBSTR( p_clob, 255, l_offset ) );
l_offset := l_offset + 255;
END LOOP;
END;